<%
'**************************************************
'函数名GetLenStr(str,strlen)
'作 用：截取普通的字符串
'参 数：str ----原字符串
'参 数：strlen ----截取字符串指定长度
'返回值：截取指定长度后的字符串
'**************************************************
Function GetLenStr(str,strlen)
	if(len(str)<=strlen) then
	GetLenStr=str
	else
	GetLenStr=left(str,strlen)&"..."
	end if
End Function
'**************************************************
'函数名GetArtStr(str,strlen)
'作 用：截取可能含有html标记的字符串
'参 数：str ----原字符串
'参 数：strlen ----截取字符串指定长度
'返回值：截取指定长度后的字符串
'**************************************************
Function GetArtStr(str,strlen)
	str=RemoveHTML(str)
	if(len(str)<=strlen) then
	GetArtStr=str
	else
	GetArtStr=left(str,strlen)&"..."
	end if
End Function
'=========================================================
'函数：RemoveHTML(strHTML)
'功能：去除HTML标记
'参数：strHTML --要去除HTML标记的字符串
'=========================================================
Function RemoveHTML(strHTML) 
	Dim objRegExp, Match, Matches 
	Set objRegExp = New Regexp 
	objRegExp.IgnoreCase = True 
	objRegExp.Global = True 
	'取闭合的<> 
	objRegExp.Pattern = "<.+?>" 
	'进行匹配 
	Set Matches = objRegExp.Execute(strHTML) 
	' 遍历匹配集合，并替换掉匹配的项目 
	For Each Match in Matches 
		strHtml=Replace(strHTML,Match.Value,"") 
	Next 
	RemoveHTML=strHTML 
	Set objRegExp = Nothing 
	set Matches=nothing
End Function 
%>